/ScriptServ

; All Coding is Copyrighted (c) 2001 by Jerry Horn
; You must contact for permission before using this
; script in any release of a mIRC Script, or on
; a mirc scripting download page.
;
; ^Jerry - jerry@whatevah.com

;menu channel {
;  Quiet List Editor:/quietlist
;}

alias quietlist dialog -m quiet quiet
dialog quiet {
  title "Quiet List Editor by ^Jerry"
  option dbu
  size -1 -1 195 188

  text "This is a simple script for editing the Quiet list on ChatSpace server rooms." , 6 , 5 5 180 45
  list 7, 5 30 120 150, hsbar,vsbar
  button "Remove" , 8 , 140 35 40 13
  button "Close" , 9 , 140 170 42 15 , ok
  combo 10 , 128 90 60 60 , sort drop
  edit "" , 11 , 128 100 60 9
  text "Channel" , 4 , 128 80 40 10
  button "Get" , 12 , 139 111 20 10
  text "" , 13 , 5 20 100 10
  button "Remove all" , 14 , 15 174 70 11

}
on *:dialog:quiet:*:*: {
  if ($devent == init) {
    set -u0 %rooms.in $chan(0)
    did -ac $dname 10 -Choose a Room-
    if (%rooms.in == 0) { did -a $dname 10 Not currently in any rooms }

    while (%rooms.in != 0) {
      did -a $dname 10 $chan(%rooms.in)
      dec %rooms.in
    }
  }
  if ($devent == sclick) && ($did == 10) {
    set -u0 %did.sel $did(10,$did(10).sel)
    if ($chr(35) == $left(%did.sel,1)) { did -r $dname 11,7,13 | did -a $dname 11 %did.sel | did -a $dname 13 $did(11) | .raw mode %did.sel +q }
  }
  if ($devent == sclick) && ($did == 12) {
    if ($chr(35) == $left($did(11),1)) { did -r $dname 7,13 | did -a $dname 13 $did(11) | .raw mode $did(11) +q }
  }
  if ($devent == sclick) && ($did == 8) { tokenize 32 $did(7, [ $did(7).sel ] ) | mode $did(13) -q $1 | did -d $dname 7 $did(7).sel }
  if ($devent == dclick) && ($did == 7) { tokenize 32 $did(7, [ $did(7).sel ] ) | mode $did(13) -q $1 | did -d $dname 7 $did(7).sel }
  if ($devent == sclick) && ($did == 14) { quiet.remall $did(13) $?!="Do you want to remove ALL quiets in this room?" }
}
raw 377:*: { if ($dialog(quiet)) { did -a quiet 7 $3 $4 $asctime($5) | .timerresize 1 1 did -z quiet 7 | halt } }
alias -l quiet.remall {
  if ($2 == $true) { mode $1 -q -b | did -r quiet 7 }
}